CIVIC(シビック)FL1のOBD2基礎編：Arduinoを使用したデータ取得

目次

• 必要な機材
• ハードウェアセッティング
• FL1シビックのOBD2通信規格
• Arduinoスケッチ１（動作確認用）
• FL1シビックがサポートしているPIDは？
• データ取得状況の確認

このページの目的

いまどきの車では、OBD（OnBoardDialog）によりいろんなデータが取得できる。それを利用した各種インジケーターも販売されているが、自分の欲しいデータを数値で取得できれば、いろんな使い道がある、はずなんだよね。

必要な機材

まずは必要な機材をそろえよう。今回購入したのは以下の４点だ。

SUNFOUDER Arduino UNO (互換機)

ちょっと安かった、気がする。

SeeedStudio CAN-BUSシールド V2

https://wiki.seeedstudio.com/CAN-BUS_Shield_V2.0/
個別にパーツをそろえて組み上げるより楽ちんだ。

SeeedStudio DB9-OBD2ケーブル（スイッチ付）

ケーブル製作しなくていいので楽ちんだ。（注意点あり。後述）

UNO用アクリルケース

ネットショップから適当に購入

ArduinoUNO互換機＋ケース

SeeedStudio CAN-BUS Shield V2

SeeedStudio DB9-OBD2ケーブル

▲目次に戻る

ハードウェアセッティング

つづいてハード的な注意点（？）など

CANバスの終端抵抗

CANバスの終端には信号反射防止のための抵抗が必要で、CAN-BUSシールドでもデフォルトでは有効になっている。今回はとりあえずシールド裏面の【P1】をカッターで切断（基板内部で接続している）し無効にしてみた。有効のままでも通信できれば何ら問題はない。

CANバス終端抵抗を無効に

参考資料：

https://files.seeedstudio.com/wiki/CAN-BUS-Shield-V2.0/res/CAN-BUS Shield v2.0.pdf

ケーブル

ケーブル途中にスイッチがあり、OBD2コネクタからの電源供給をON/OFFできるんだけど、なんか違和感が．．．まぁ、覚えてしまえば問題なしだが。

ケーブル途中のスイッチ（これでON）

また、ピンアサインは以下のとおりだ。

DSUBピンアサイン

番号	信号
1	GND
2	GND
3	CAN H
4	K LINE
5	CAN L
6	J1850 -
7	J1850 +
8	L LINE
9	V

FL1シビックは、ISO15765-4のCANバス通信を使用しているが、車種によっては、J1850やK(L)LINEを使用した通信を行っているので注意が必要だ。ちなみに、CAN-BUSシールドは、J1850やK(L)LINEには対応していない。

CAN-BUSシールドとUNO互換機

CAN-BUSシールドをUNOにドッキングしてみよう．．．あれっ？　USBコネクターの金属カバーとDSUBコネクターの足が干渉するんだけど．．．

DSUB足とUSBコネクターが干渉

実際に干渉しているのは、7番ピン（J1850+）１本だけで、今回は使用しない信号（シールド側は配線されていない、車体側でも信号は流れていない、はず）だったので問題なしとするが、シールド設計として、これは無いんじゃないの？

▲目次に戻る

FL1シビックのOBD2通信規格

どうも最近のホンダ車は「ISO157654-4　29bitID」での通信らしい。いったいどんな通信なんだ？

参考リンク：

https://sourceforge.net/p/rusefi/tickets/_discuss/thread/65c5390c/5610/attachment/iso_15765-4.pdf

その他、ネットを徘徊して情報を収集し、自分なりには下記の理解となった（間違ってたらゴメン）

▲目次に戻る

Arduinoスケッチ１（動作確認用）

さて、ハードの準備ができたら、Arduinoのスケッチ作成のため、ライブラリをダウンロード＆インクルードしよう。
https://github.com/Seeed-Studio/Seeed_Arduino_CAN

インクルードしたら、さっそくサンプルスケッチを読み込みだ。

CAN-BUSシールドサンプルスケッチ

が、ここではっきりしておこう。これらのサンプルスケッチはあくまでのプログラムのサンプルであって、動作するサンプルでは無い！（なかには動くのもあるかもしれないが）　よって、サンプルの「send_recieve」と「recieve_monitor」を参考にコーディングしていくことにする。

#include <SPI.h>
#include "mcp2515_can.h"

const int CAN_CS_PIN = 9;
const int CAN_INT_PIN = 2;   //サンプルだと「10」の場合あり。「int」ピンは「2」（機器仕様）。今回は使わない

mcp2515_can CAN(CAN_CS_PIN);

unsigned char len = 0;
unsigned char buf[8];
uint32_t id;

void setup() {
  SERIAL_PORT_MONITOR.begin(115200);
  while(!Serial);
  if (CAN.begin(CAN_500KBPS) != 0) {
    SERIAL_PORT_MONITOR.println("CAN-BUS init error!");
    while(1);
  }
  SERIAL_PORT_MONITOR.println("CAN-BAS init ok!");

  // フィルターの設定　注１
  CAN.init_Mask(0 , 1 , 0x00000000);
  CAN.init_Filt(0 , 1 , 0x00000000);
  CAN.init_Filt(1 , 1 , 0x00000000);
  
  CAN.init_Mask(1 , 1 , 0x00000000);
  CAN.init_Filt(2 , 1 , 0x00000000);
  CAN.init_Filt(3 , 1 , 0x00000000);
  CAN.init_Filt(4 , 1 , 0x00000000);
  CAN.init_Filt(5 , 1 , 0x00000000);
}

unsigned char stmp[8] = {0x02 , 0x01 , 0x0C , 0x00 , 0x00 , 0x00 , 0x00 , 0x00};  //注２
void loop() {
  unsigned long t = millis();

  CAN.sendMsgBuf(0x18DB33F1 , 1 , 8 , stmp);    //注３

  CAN.readMsgBuf(&len , buf);
  id = CAN.getCanId();

  SERIAL_PORT_MONITOR.print(t); SERIAL_PORT_MONITOR.print(":");
  SERIAL_PORT_MONITOR.print(id , HEX); SERIAL_PORT_MONITOR.print(":");
  for (int i = 0; i < len; i++) {
    SERIAL_PORT_MONITOR.print(buf[i] , HEX); SERIAL_PORT_MONITOR.print(" ");    //注４
  }
  SERIAL_PORT_MONITOR.print("|");
  SERIAL_PORT_MONITOR.print((buf[3]*256 + buf[4])/4);    //注４
  SERIAL_PORT_MONITOR.println("rpm");
  delay(100);
}

注１：フィルター設定

CAN-BUSシールド上のCAN通信デバイス「MCP2515」には、（車両にはいろんな信号が流れているので、欲しい信号だけを抽出できるよう）信号のフィルタリング機能（マスク1[フィルタ0、1と連動]、マスク1[フィルタ2、3、4、5と連動]）が搭載されている。ここで、デフォルトがどんな状態か知らないので、念のため、全部通してもらうように設定しておく。

注２：送信内容

OBD2での送信内容は以下のフォーマットによる。

注３：送信コマンド

前述のように、FL1シビックは「ISO157654-4　29bitID」での通信なので、CAN-BUSシールドの送信コマンドは下記になる。

注４：受信データ

受信データは以下のフォーマットになる。

動作例

では実機での確認だ。無事にデータ取得できているようだ。

ちなみに、シビック車体側のOBD2コネクターと購入したケーブルの相性が悪いのかどうか、かなり力を入れて差し込まないと、通信ができなかったことを付け加えておく（実はかなり悩んだ。「電源はとれるのに通信できねぇーーー。いったい何が悪いんだ．．．」）

OBD2通信動作確認

『ECUEF』さん、回答ありがとう。これからよろしく。

▲目次に戻る

FL1シビックがサポートしているPIDは？[2023-07-23 updateed]

無事、通信できるようになったので、FL1シビックがサポートしているパラメータIDを調べてみよう（どんなデータが取れるの？）。そのためには、前項の『注２：送信内容』の『パラメータID』を下記に変更してリクエストを投げればokだ。（参考：https://en.wikipedia.org/wiki/OBD-II_PIDs）

で、返ってきたのが以下の値だ。

おっと、『ECUEF』さんだけでなく、『ECU10』さんもデータを出してくれるらしいぞ。よろしく。

ビットが「1」のパラメータIDはECUが「データを出せるよ」と言ってくれているので、それを整理しよう。（参考：https://en.wikipedia.org/wiki/OBD-II_PIDs）

注：PDI15のO2センサの値の参照が間違っていた！　ここ以降の空燃比に関する記述は誤りだ

データサンプル

「このデータなら出してあげられるよ」とECUが教えてくれたデータから、楽しそうなデータを試しに取得してみた。おそらく取れているんじゃないかと。グラフの横軸の単位はmsecで、縦軸は各グラフ注釈を参照のこと。ちなみに取得したタイミングは別なので各グラフに相関関係は無い。

インマニ圧力[kPa絶対圧]@アイドリング

点火時期[deg上死点前]@アクセル操作あり

アクセル開度[%]

冷却水温[℃]

データ取得状況の確認

シリアルモニターでデータを確認するのも面倒なので、家に転がっていた液晶モニター（キャラクター表示用）を接続し出力してみた。表示文字数が限られているのでデータを厳選して連続取得した状況を載せておこう。うん、やっぱり、こうやって「見える化」すると（するのも）楽しいね。妄想は膨らむばかりだ。

購入品（今回は家内パーツストックから使用）

液晶ディスプレイ（16x2キャラクタ表示用）：OYOSO I2C 1602 LCD

液晶ディスプレイを追加

今回の取得データ

表示位置	データ
左上	インマニ絶対圧[kPa]
右上	回転数[rpm]
左下	スロットル開度[%]
右下	空燃比λ

OBD2データ取得状況

Arduinoスケッチ

#include <SPI.h>
#include <mcp2515_can.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27,16,2);

const int CAN_CS_PIN = 9;
const int CAN_INT_PIN = 2;
mcp2515_can CAN(CAN_CS_PIN);

unsigned char len = 0;
uint32_t id;
String unit;
float data;
unsigned char Col;
unsigned char Row;
unsigned char fct;
unsigned char buf[8];
unsigned char stmp[] = {0x02, 0x01, 0x0C, 0x00, 0x00, 0x00, 0x00, 0x00};
unsigned char cmnd[] = {0x0B, 0x0C, 0x11, 0x15};
unsigned long trgt[] = {0x18DA10F1, 0x18DAEFF1, 0x18DAEFF1, 0x18DA10F1};
unsigned long ti;

void setup() {
  lcd.init();
  lcd.backlight();
  SERIAL_PORT_MONITOR.begin(115200);
  while(!Serial);
  if (CAN.begin(CAN_500KBPS) != 0) {
    lcd.setCursor(1,0);
    lcd.print("CAN-BUS init error!");
    while(1);
  }
  lcd.setCursor(1,0);
  lcd.print("CAN-BAS init ok!");

  CAN.init_Mask(0 , 1 , 0x00000000);  //全部通過
  CAN.init_Filt(0 , 1 , 0x18DAF110);
  CAN.init_Filt(1 , 1 , 0x18DAF1EF);
  CAN.init_Mask(1 , 1 , 0xFFFFFFFF);  //0x00000000のみ通過
  CAN.init_Filt(2 , 1 , 0x00000000);
  CAN.init_Filt(3 , 1 , 0x00000000);
  CAN.init_Filt(4 , 1 , 0x00000000);
  CAN.init_Filt(5 , 1 , 0x00000000);

  delay(1000);
  lcd.clear();
}

void loop() {
  for (int i=0; i<4; i++) {
    ti = millis();
    unit = "";
    stmp[2] = cmnd[i];
    CAN.sendMsgBuf(trgt[i], 1,8, stmp);
    if(CAN.checkReceive()) {
      CAN.readMsgBuf(&len, buf);
      switch (buf[2]) {
        case 0x0B:
          data=buf[3];
          fct = 0;
          unit = "kPa";
          Col = 0; Row=0;
          break;
        case 0x0C:
          data=((float)256*buf[3]+buf[4])/4;
          fct = 0;
          unit = "rpm";
          Col = 8;Row=0;
          break;
        case 0x11:
          data=(float)100*buf[3]/255;
          fct = 1;
          unit = "%";
          Col=0;Row=1;
          break;
        case 0x15:
          data=((float)256*buf[3]+buf[4])/32768;  //間違っている
          fct = 2;       //間違っている
          unit = "AFR";  //間違っている
          Col=8;Row=1;   //間違っている
          break;
      }
    }
    lcd.setCursor(Col,Row);lcd.print(data,fct);lcd.print(unit);
    SERIAL_PORT_MONITOR.print(ti);SERIAL_PORT_MONITOR.print(":");
    SERIAL_PORT_MONITOR.print(buf[2],HEX);SERIAL_PORT_MONITOR.print(":");
    SERIAL_PORT_MONITOR.print(data, fct);SERIAL_PORT_MONITOR.print(unit);SERIAL_PORT_MONITOR.print("|");
    //delay(500);
  }
  SERIAL_PORT_MONITOR.println("");
  delay(200);
}

▲目次に戻る

『応用編』に続く．．．

この企画もページが長くなってきたので、別ページ『CIVIC(シビック)FL1のOBD2応用編：データロギングと解析』へ続く。